Framework Reinit Doesn't Recognize Webroot Setting in server.json

[homestar9]

What are the steps to reproduce this issue?

1. Create a new app using the Ortus Module Template
2. Add a server.json file to the project root and make sure the web.webroot value is set to test-harness

// example server.json
{
 "name":"myapp",
 "app":{
 "serverHomeDirectory":".engine/lucee5",
 "cfengine":"lucee@5"
 },
 "web":{
 "http":{
 "port":"60301"
 },
 "rewrites":{
 "enable":"true"
 },
 "webroot":"test-harness",
 "aliases":{
 "/moduleroot/myapp":"./",
 "/modules/myapp":"./"
 }
 },
 "openBrowser":"false",
 "cfconfig":{
 "file":".cfconfig.json"
 }
}

3. Start the server from the root
4. Try typing fwreinit in Commandbox

What happens?

You will see the error No server configurations found for '[your project folder]', so have no clue what to reinit buddy!

What were you expecting to happen?

The Coldbox-CLI should see the web root and attempt to reinit the framework.

What versions are you using?

Tested with coldbox-cli@be and Commandbox 6.0.0

[homestar9]

Update:
If I make the following change to Line 29 of reinit.cfc:
var serverInfo = serverService.getServerInfoByDiscovery( name = arguments.name );

The reinit will work if you specify the name of the server like this:
fwreinit name=mymodule

However, I think fwreinit should be smart enough to infer the name from the current working directory server.json file or box.json, if present.

Therefore, I think the fix involves making the change I mentioned above and also changing the default name argument in the run() method to look for a value in the server.json file followed next by box.json.

[homestar9]

Update 2:
What about this possible solution?

/**
 * Reinitialize a running ColdBox app if a server was started with CommandBox.
 * This command must be ran from the root of the ColdBox Application
 * .
 * {code:bash}
 * coldbox reinit
 * {code}
 * .
 * {code:bash}
 * coldbox reinit password="mypass"
 * {code}
 **/
component aliases="fwreinit" {

	// DI
	property name="serverService" inject="ServerService";
	property name="formatter" inject="formatter";

	/**
	 * @password The FWReinit password
	 * @name Name of the CommandBox server to reinit, will default to the name listed in server.json file
	 * @showUrl Show the Url to reinit
	 **/
	function run(
		password = "1",
		name = getDefaultServerName(),
		showUrl = true
	){
		var serverInfo = serverService.getServerInfoByDiscovery( name = arguments.name );

		if ( !structCount( serverInfo ) ) {
			print.boldRedLine(
				"No server configurations found for '#getCWD()#' and '#arguments.name#', so have no clue what to reinit buddy!"
			);
		} else {
			var thisURL = "#serverInfo.host#:#serverInfo.port#/?fwreinit=#arguments.password#";
			if ( arguments.showUrl ) {
				print.greenLine( "Hitting... #thisURL#" );
			}
			http result="local.results" url="#thisURL#";

			if ( findNoCase( "200", local.results.statusCode ) ) {
				print.boldGreenLine( "App Reinited!" );
			} else {
				print
					.redLine( "status code: #local.results.statusCode#" )
					.redline( "error detail: " & local.results.errorDetail )
					.line( trim( formatter.HTML2ANSI( local.results.filecontent ) ) );
			}
		}
	}
	
	private function getDefaultServerName() {
		return serverService.getServerInfoByDiscovery( serverConfigFile = 'server.json' ).name;
	}

}

[lmajano]

I totally dropped the ball on this @homestar9 Can we rekindle this one

[homestar9]

Hi @lmajano, no worries. I know you're "all hands on deck" with Boxlang these days. I'll be happy to revive this issue and ensure I can still replicate it the same way.

[lmajano]

Gracias. I am trying to.clean now all the module issues now that we are stable

[lmajano]

Ok, If you want to re-address this, we need to do it for the modern and boxlang templates now.

[homestar9]

Thanks, @lmajano ! I’d like to re-address it, but I’m not entirely clear on what you mean by “for the modern and boxlang templates.” Could you clarify which templates specifically you’re referring to and what needs to be adjusted in each? I just want to make sure I understand the scope before proceeding. I don't have a lot of experience making changes to the coldbox-cli, so I'm learning as I'm going here.

[lmajano]

Sorry, I left you in the dark here. Let's try again please. Let me know what you need

[homestar9]

@lmajano I believe my fix here should work: #9 (comment)

I'm not sure what you mean by adding it to the modern or boxlang templates. Fixing the issue in the CLI should impact all of the Coldbox templates, AFAIK.

[lmajano]

Done, please test

[homestar9]

Confirmed working on @be!