Bug 1409957 - Create polling daemon to query Phabricator for recent transcations and update bug data according to revision changes

extensions/PhabBugz/Extension.pm

@@ -10,10 +10,20 @@ package Bugzilla::Extension::PhabBugz;
 use 5.10.1;
 use strict;
 use warnings;
+
 use parent qw(Bugzilla::Extension);
 
+use Bugzilla::Constants;
+use Bugzilla::Extension::PhabBugz::Feed;
+use Bugzilla::Extension::PhabBugz::Logger;
+
 our $VERSION = '0.01';
 
+BEGIN {
+    *Bugzilla::User::phab_phid = sub { return $_[0]->{phab_phid}; };
+    *Bugzilla::User::phab_review_status = sub { return $_[0]->{phab_review_status}; };
+}
+
 sub config_add_panels {
     my ($self, $args) = @_;
     my $modules = $args->{panel_modules};
@@ -40,4 +50,47 @@ sub webservice {
     $args->{dispatch}->{PhabBugz} = "Bugzilla::Extension::PhabBugz::WebService";
 }
 
+#
+# installation/config hooks
+#
+
+sub db_schema_abstract_schema {
+    my ($self, $args) = @_;
+    $args->{'schema'}->{'phabbugz'} = {
+        FIELDS => [
+            id => {
+                TYPE       => 'INTSERIAL',
+                NOTNULL    => 1,
+                PRIMARYKEY => 1,
+            },
+            name => {
+                TYPE    => 'VARCHAR(255)',
+                NOTNULL => 1,
+            },
+            value => {
+                TYPE    => 'MEDIUMTEXT',
+                NOTNULL => 1
+            }
+        ],
+        INDEXES => [
+            phabbugz_idx => {
+                FIELDS => ['name'],
+                TYPE => 'UNIQUE',
+            },
+        ],
+    };
+}
+
+sub install_filesystem {
+    my ($self, $args) = @_;
+    my $files = $args->{'files'};
+
+    my $extensionsdir = bz_locations()->{'extensionsdir'};
+    my $scriptname = $extensionsdir . "/PhabBugz/bin/phabbugzd.pl";
+
+    $files->{$scriptname} = {
+        perms => Bugzilla::Install::Filesystem::WS_EXECUTE
+    };
+}
+
 __PACKAGE__->NAME;

extensions/PhabBugz/bin/phabbugz_feed.pl

@@ -0,0 +1,50 @@
+#!/usr/bin/perl
+
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+# This Source Code Form is "Incompatible With Secondary Licenses", as
+# defined by the Mozilla Public License, v. 2.0.
+
+use 5.10.1;
+use strict;
+use warnings;
+
+use lib qw(. lib local/lib/perl5);
+
+BEGIN {
+    use Bugzilla;
+    Bugzilla->extensions;
+}
+
+use Bugzilla::Extension::PhabBugz::Daemon;
+Bugzilla::Extension::PhabBugz::Daemon->start();
+
+=head1 NAME
+
+phabbugz_feed.pl - Query Phabricator for interesting changes and update bugs related to revisions.
+
+=head1 SYNOPSIS
+
+  phabbugz_feed.pl [OPTIONS] COMMAND
+
+    OPTIONS:
+      -f        Run in the foreground (don't detach)
+      -d        Output a lot of debugging information
+      -p file   Specify the file where phabbugz_feed.pl should store its current
+                process id. Defaults to F<data/phabbugz_feed.pl.pid>.
+      -n name   What should this process call itself in the system log?
+                Defaults to the full path you used to invoke the script.
+
+    COMMANDS:
+      start     Starts a new phabbugz_feed daemon if there isn't one running already
+      stop      Stops a running phabbugz_feed daemon
+      restart   Stops a running phabbugz_feed if one is running, and then
+                starts a new one.
+      check     Report the current status of the daemon.
+      install   On some *nix systems, this automatically installs and
+                configures phabbugz_feed.pl as a system service so that it will
+                start every time the machine boots.
+      uninstall Removes the system service for phabbugz_feed.pl.
+      help      Display this usage info

extensions/PhabBugz/bin/update_project_members.pl

@@ -20,11 +20,9 @@
 use Bugzilla::Error;
 use Bugzilla::Group;
 
+use Bugzilla::Extension::PhabBugz::Project;
 use Bugzilla::Extension::PhabBugz::Util qw(
-    create_project
-    get_members_by_bmo_id
-    get_project_phid
-    set_project_members
+    get_phab_bmo_ids
 );
 
 Bugzilla->usage_mode(USAGE_MODE_CMDLINE);
@@ -55,23 +53,22 @@
 my $sync_groups = Bugzilla::Group->match({ name => [ split('[,\s]+', $phab_sync_groups) ] });
 
 foreach my $group (@$sync_groups) {
-    my @users = get_group_members($group);
-
     # Create group project if one does not yet exist
     my $phab_project_name = 'bmo-' . $group->name;
-    my $project_phid = get_project_phid($phab_project_name);
-    if (!$project_phid) {
-        $project_phid = create_project($phab_project_name, 'BMO Security Group for ' . $group->name);
+    my $project = Bugzilla::Extension::PhabBugz::Project->new({
+        name => $phab_project_name
+    });
+    if (!$project->id) {
+        $project = Bugzilla::Extension::PhabBugz::Project->create({
+            name        => $phab_project_name,
+            description => 'BMO Security Group for ' . $group->name
+        });
     }
 
-    # Get the internal user ids for the bugzilla group members
-    my $phab_user_ids = [];
-    if (@users) {
-        $phab_user_ids = get_members_by_bmo_id(\@users);
-    }
+    my @group_members = get_group_members($group);
 
-    # Set the project members to the exact list
-    set_project_members($project_phid, $phab_user_ids);
+    $project->set_members(\@group_members);
+    $project->update();
 }
 
 sub get_group_members {
@@ -84,5 +81,13 @@ sub get_group_members {
             $users{$user->id} = $user;
         }
     }
-    return values %users;
-}
+
+    # Look up the phab ids for these users
+    my $phab_users = get_phab_bmo_ids({ ids => [ keys %users ] });
+    foreach my $phab_user (@{ $phab_users }) {
+        $users{$phab_user->{id}}->{phab_phid} = $phab_user->{phid};
+    }
+
+    # We only need users who have accounts in phabricator
+    return grep { $_->phab_phid } values %users;
+}

extensions/PhabBugz/lib/Constants.pm

@@ -16,10 +16,12 @@ our @EXPORT = qw(
     PHAB_AUTOMATION_USER
     PHAB_ATTACHMENT_PATTERN
     PHAB_CONTENT_TYPE
+    PHAB_POLL_SECONDS
 );
 
 use constant PHAB_ATTACHMENT_PATTERN => qr/^phabricator-D(\d+)/;
 use constant PHAB_AUTOMATION_USER    => 'phab-bot@bmo.tld';
 use constant PHAB_CONTENT_TYPE       => 'text/x-phabricator-request';
+use constant PHAB_POLL_SECONDS       => 5;
 
 1;

extensions/PhabBugz/lib/Daemon.pm

@@ -0,0 +1,100 @@
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+# This Source Code Form is "Incompatible With Secondary Licenses", as
+# defined by the Mozilla Public License, v. 2.0.
+
+package Bugzilla::Extension::PhabBugz::Daemon;
+
+use 5.10.1;
+use strict;
+use warnings;
+
+use Bugzilla::Constants;
+use Bugzilla::Extension::PhabBugz::Feed;
+use Bugzilla::Extension::PhabBugz::Logger;
+
+use Carp qw(confess);
+use Daemon::Generic;
+use File::Basename;
+use File::Spec;
+use Pod::Usage;
+
+sub start {
+    newdaemon();
+}
+
+#
+# daemon::generic config
+#
+
+sub gd_preconfig {
+    my $self = shift;
+    my $pidfile = $self->{gd_args}{pidfile};
+    if (!$pidfile) {
+        $pidfile = File::Spec->catfile(bz_locations()->{datadir}, $self->{gd_progname} . ".pid");
+    }
+    return (pidfile => $pidfile);
+}
+
+sub gd_getopt {
+    my $self = shift;
+    $self->SUPER::gd_getopt();
+    if ($self->{gd_args}{progname}) {
+        $self->{gd_progname} = $self->{gd_args}{progname};
+    } else {
+        $self->{gd_progname} = basename($0);
+    }
+    $self->{_original_zero} = $0;
+    $0 = $self->{gd_progname};
+}
+
+sub gd_postconfig {
+    my $self = shift;
+    $0 = delete $self->{_original_zero};
+}
+
+sub gd_more_opt {
+    my $self = shift;
+    return (
+        'pidfile=s' => \$self->{gd_args}{pidfile},
+        'n=s'       => \$self->{gd_args}{progname},
+    );
+}
+
+sub gd_usage {
+    pod2usage({ -verbose => 0, -exitval => 'NOEXIT' });
+    return 0;
+};
+
+sub gd_redirect_output {
+    my $self = shift;
+
+    my $filename = File::Spec->catfile(bz_locations()->{datadir}, $self->{gd_progname} . ".log");
+    open(STDERR, ">>", $filename) or (print "could not open stderr: $!" && exit(1));
+    close(STDOUT);
+    open(STDOUT, ">&", STDERR) or die "redirect STDOUT -> STDERR: $!";
+    $SIG{HUP} = sub {
+        close(STDERR);
+        open(STDERR, ">>", $filename) or (print "could not open stderr: $!" && exit(1));
+    };
+}
+
+sub gd_setup_signals {
+    my $self = shift;
+    $self->SUPER::gd_setup_signals();
+    $SIG{TERM} = sub { $self->gd_quit_event(); }
+}
+
+sub gd_run {
+    my $self = shift;
+    $::SIG{__DIE__} = \&Carp::confess if $self->{debug};
+    my $phabbugz = Bugzilla::Extension::PhabBugz::Feed->new();
+    $phabbugz->is_daemon(1);
+    $phabbugz->logger(
+        Bugzilla::Extension::PhabBugz::Logger->new(debugging => $self->{debug}));
+    $phabbugz->start();
+}
+
+1;